Bruker du Office 365 er det mye som blir lettere. Inkludert å hente data fra flere ark eller faner i Excel. Slik lager du en felles liste, og rapport for flere selgere per måned.

Video instruksjon.

---

Hente data fra flere ark i Excel.

I dette eksempelet skal vi hente salgsdata fra flere ark i Excel. Hver fane inneholder en salgs rapport med selger og omsetning.

Forberedelser

I hvert ark, eller fane ligger det salgsdata for den aktuelle måneden. Den bør starte i samme rad, og samme kolonne i alle arkene.

---

Hente data med VSTAKK

Excel funksjonen Vstakk slår sammen to eller flere lister til en liste. Enten listene er i samme regneark eller flere regneark.

Funksjon: VSTAKK(Jan:Des!B4:C14)

Den stabler data fra alle arkene i en liste, basert på innholdet fa B4 til C14 i alle arkene.

Tips: marker først cellene i det første arket (her jan), hold Shift tasten inne og trykk på det siste arket. (Her des).

Bli kvitt unødvendige rader.

Det ligger ikke data i alle arkene fra B4:C14, så vi skal ta bort de unødvendige radene, og det gjør vi ved å utelukke alle med 0.

FILTRER(VSTAKK(Jan:Des!B4:C14);VSTAKK(Jan:Des!B4:B14)<>0;»»)

Vi filtrer resultatet fra Vstakk, når Vstakk returnerer noe annet enn 0 i B kolonnen.

---

Lag en salgs rapport fra alle arkene.

I dette avsnittet skal vi lage en rapport per selger. Det første du bør gjøre er å lage en liste med unik forekomster, så selgerne kommer kun en gang.

=UNIK(INDEKS(FILTRER(VSTAKK(Jan:Des!B4:C14);VSTAKK(Jan:Des!B4:B14)<>0;»»);;1))

Forklaring til formelen.

INDEKS(FILTRER(VSTAKK(Jan:Des!B4:C14);VSTAKK(Jan:Des!B4:B14)<>0;»»);;1) VSTAKK generer en liste med 2 kolonner. Indeks gjør det mulig å hente kun en kolonne. Her ønsker vi den første kolonnen, den med selgerne. Derfor avsluttes den med 1.

UNIK sørger for at hver selger komme en gang. Så kan vi summere salgene per selger.

Summer salg per selger.

Vi bruker SUMMER.HVIS.SETT, sammen med INDEKS, for å skille på kolonnen med selger navn, og salg.

SUMMER.HVIS.SETT(INDEKS(B4#;;2);INDEKS(B4#;;1);E4#)

Vi bruker INDEKS som tidligere, vi skal tallene som er i kolonne 2. Når navnet som står i kolonne 1 stemmer med navne fra UNIK funksjonen (her E4#)

Bruk av #. Office 365 versjonen av Excel gir deg mulighet til å jobbe med dynamiske lister. Ved å bruke # sammen med celle referansen E4#, lar vi Excel styre hvor mange rader (eventuelt kolonner) det er i datalisten. Så vi slipper å oppdatere formlene når datasettet endrer seg.

---

Excel LAMBDA-funksjonen er en måte å lage egne tilpassede funksjoner som kan gjenbrukes gjennom en arbeidsbok, uten VBA eller makroer.

Ofte gjentar vi de samme formlene flere steder i det samme regnearket. Med Lambda funksjonen kan du skriver formelen en gang, og gjenta den på en enkel måte.

---

Bruk av lambda.

Det er 2 steg du må gjøre når du skal benytte Lambda:

• Lage og sjekke formelen.
• Definere formelen som et navn.

---

Lambda eksempler.

Lambda funksjonen er: =f_summerxogy(C3;C4)

f_summerxogy er et eget definert navn

Det refereres til Lambda funksjonen. Lambda funksjonen i Excel har 2 argumenter. Først ett eller flere parametere (navn) som du skal gjøre i den siste delen, beregningen.

Parameterne i eksemplet er X og Y. Beregningen er X+Y.

Slik gjør du:

1. Skriv først selve funksjonen: =Lambda(X;Y;X+Y)
2. Lambda(X;Y;X+Y) gir en feilmelding når det står alene i regnearket, for det er ingen X og Y. Test den med å skrive =Lambda(X;Y;X+Y)(3;4) – Vill summere 3 og 4.
3. Kopier Lambda(X;Y;X+Y), lim det inn i Formler, med eget navn. Bruk navnet du har angitt, for å gjenta den samme formelen.

---

Lambda videoforklaring.

For å vise deg hvordan Lambda funger på norsk, kan du se videoforklaringen

---

Last ned regneark med eksempler.

Til slutt, last ned eksemplene på Lambda her:

---

Om Hogstad Rådgivning.

Slik kan du fjerne duplikater i Excel med en formel, og få en liste med unike verdier. Oppdag 2 måter å gjøre det på.

---

Alternativ 1: Fjern duplikater, behold utseende.

Med denne formelen beholder du det samme antall rader i Excel, men duplikater er fjernet, eller erstattet.

Formel:

=HVIS(SEKVENS(ANTALLA(B4:B11))=XSAMSVAR(B4:B11;B4:B11);INDEKS(B4:B11;SEKVENS(ANTALLA(B4:B11)));»–«)

Forklaring:

Hvis sammenligner resultatet av Sekvens (lager en tallrekke fra 1 til det antall rader som ikke er tomme) med resultatet av Xsamsvar, som lager en liste verdien fra første gangen en tekst dukker opp i liste.

Når det er sant, viser Indeks resultatet fra listen, når det er usant, vises — eller det du velger innenfor «».

Video forklaring

---

Lag en Unik liste i Excel.

Det finnes en egen funksjon i Excel som bare henter en Unik liste. Den kan du benytte i stedet for formelen. Om målet ditt bare er å ha en liste fri for duplikater.

Formel:

=UNIK(B4:B11)

Forklaring:

Lager en dynamisk liste med unike verdier, fra utvalget. (B4:B11)

---

Om Hogstad Rådgivning

Sammenligne 2 kolonner i Excel. For å finne duplikater. Med en enkel formel kan finne hva som er i både kolonne 1 og kolonne 2.

---

Formelen for å sammenligne 2 kolonner i Excel.

=FILTRER(Tabell2[Navn];ERTALL(XSAMSVAR(Tabell2[Navn];Tabell1[Navn])))

Formelen for å sammenligne 2 lister eller kolonner i Excel består av 3 steg:

Steg 1:

XSAMSVAR(Tabell2[Navn];Tabell1[Navn])

Forklaring.

Xsamvar slår opp verdiene i liste 2, og sammenligner med innholdet i liste 1. Reultatet er en lang list, som enten er en feilmelding, eller en tallverdi. Er det en tallverdi, så er innholdet i listene duplikater.

Steg 2:

ERTALL(XSAMSVAR(Tabell2[Navn];Tabell1[Navn]))

Funksjonen Ertall sjekker om resultatet av Xsamsvar er tall. Er det tall, får vi SANN (navnet er i begge listene). Får vi USANN er ikke navnet i begge listene.

Steg 3:

=FILTRER(Tabell2[Navn];ERTALL(XSAMSVAR(Tabell2[Navn];Tabell1[Navn])))

Filtrer viser verdiene i Tabell2 når resultatet av Ertall er SANN.

---

Video: Slik finner du duplikater i 2 lister.

Se videoen der du får se det fra steg til steg.

---

.